Как определить, имеет ли переменная число в Perl?

perl numbers

117401 просмотра

15 ответа

Есть ли простой способ в Perl, который позволит мне определить, является ли данная переменная числовой? Что-то вроде:

if (is_number($x))
{ ... }

было бы идеальным. -wКонечно, предпочтителен метод, который не будет выдавать предупреждения при использовании коммутатора.

Автор: Derek Park Источник Размещён: 17.05.2019 03:31

Ответы (15)


115 плюса

Решение

Использование, Scalar::Util::looks_like_number()использующее внутреннюю функцию look_like_number () для Perl C API, что, вероятно, является наиболее эффективным способом для этого. Обратите внимание, что строки «inf» и «бесконечность» рассматриваются как числа.

Пример:

#!/usr/bin/perl

use warnings;
use strict;

use Scalar::Util qw(looks_like_number);

my @exprs = qw(1 5.25 0.001 1.3e8 foo bar 1dd inf infinity);

foreach my $expr (@exprs) {
    print "$expr is", looks_like_number($expr) ? '' : ' not', " a number\n";
}

Дает этот результат:

1 is a number
5.25 is a number
0.001 is a number
1.3e8 is a number
foo is not a number
bar is not a number
1dd is not a number
inf is a number
infinity is a number

Смотрите также:

Автор: nohat Размещён: 26.08.2008 04:53

23 плюса

Проверьте модуль CPAN Regexp :: Common . Я думаю, что он делает именно то, что вам нужно, и обрабатывает все крайние случаи (например, реальные числа, научную нотацию и т. Д.). например

use Regexp::Common;
if ($var =~ /$RE{num}{real}/) { print q{a number}; }
Автор: naumcho Размещён: 15.08.2008 09:01

20 плюса

Первоначальный вопрос заключался в том, как определить, является ли переменная числовой, а не «имеет числовое значение».

Существует несколько операторов, которые имеют отдельные режимы работы для числовых и строковых операндов, где «числовой» означает все, что изначально было числом или когда-либо использовалось в числовом контексте (например $x = "123"; 0+$x, перед добавлением, $xявляется строкой, затем оно считается числовым).

Один из способов сказать следующее:

if ( length( do { no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}
Автор: ysth Размещён: 27.09.2010 05:16

8 плюса

Простой (и , возможно , упрощенно) ответ на вопрос , является содержание $xчислового заключается в следующем:

if ($x  eq  $x+0) { .... }

Он выполняет текстовое сравнение оригинала $xс $xпреобразованным в числовое значение.

Автор: Peter Vanroose Размещён: 17.10.2012 03:10

7 плюса

Обычно проверка количества выполняется с помощью регулярных выражений. Этот код будет определять, является ли что-то числовым, а также проверять неопределенные переменные, чтобы не выдавать предупреждения:

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}

sub is_float {
   defined $_[0] && $_[0] =~ /^[+-]?\d+(\.\d+)?$/;
}

Вот некоторые материалы для чтения, на которые вы должны обратить внимание.

Автор: andrewrk Размещён: 15.08.2008 07:58

3 плюса

Не идеально, но вы можете использовать регулярное выражение:

sub isnumber 
{
    shift =~ /^-?\d+\.?\d*$/;
}
Автор: farmerchris Размещён: 15.08.2008 07:49

3 плюса

Я не верю, что для этого есть что-то построенное. Более того, чем вы когда-либо хотели видеть по этому вопросу, см. Perlmonks об обнаружении чисел

Автор: jsight Размещён: 15.08.2008 08:44

2 плюса

Несколько более надежное регулярное выражение можно найти в Regexp :: Common .

Похоже, вы хотите знать, думает ли Perl, что переменная является числовой. Вот функция, которая прерывает это предупреждение:

sub is_number{
  my $n = shift;
  my $ret = 1;
  $SIG{"__WARN__"} = sub {$ret = 0};
  eval { my $x = $n + 1 };
  return $ret
}

Другой вариант - отключить предупреждение локально:

{
  no warnings "numeric"; # Ignore "isn't numeric" warning
  ...                    # Use a variable that might not be numeric
}

Обратите внимание, что нечисловые переменные будут безмолвно преобразованы в 0, что, вероятно, вы так и захотите.

Автор: Jon Ericson Размещён: 15.08.2008 08:56

2 плюса

rexep не идеально ... это:

use Try::Tiny;

sub is_numeric {
  my ($x) = @_;
  my $numeric = 1;
  try {
    use warnings FATAL => qw/numeric/;
    0 + $x;
  }
  catch {
    $numeric = 0;
  };
  return $numeric;
}
Автор: fringd Размещён: 10.12.2010 06:58

1 плюс

Попробуй это:

If (($x !~ /\D/) && ($x ne "")) { ... }
Автор: CDC Размещён: 31.05.2013 04:01

1 плюс

Я нашел это интересным, хотя

if ( $value + 0 eq $value) {
    # A number
    push @args, $value;
} else {
    # A string
    push @args, "'$value'";
}
Автор: Swadhikar C Размещён: 01.10.2015 02:15

0 плюса

Лично я считаю, что путь - это полагаться на внутренний контекст Perl, чтобы сделать решение пуленепробиваемым. Хорошее регулярное выражение может соответствовать всем допустимым числовым значениям и ни одному из нечисловых (или наоборот), но поскольку существует способ использования той же логики, которую использует интерпретатор, должно быть безопаснее полагаться на это напрямую.

Поскольку я, как правило, запускаю свои сценарии -w, мне пришлось объединить идею сравнения результата «значение плюс ноль» с исходным значением с помощью no warningsподхода @ysth на основе:

do { 
    no warnings "numeric";
    if ($x + 0 ne $x) { return "not numeric"; } else { return "numeric"; }
}
Автор: zagrimsan Размещён: 31.12.2015 01:47

0 плюса

Вы можете использовать регулярные выражения, чтобы определить, является ли $ foo числом (или нет).

Взгляните сюда: как определить, является ли скаляр числом

Автор: bLIGU Размещён: 26.02.2016 04:55

-1 плюса

if (определяется $ x && $ x! ~ m / \ D /) {} или $ x = 0, если! $ Х; если ($ x! ~ m / \ D /) {}

Это небольшая вариация ответа Викея, но позвольте мне объяснить мои аргументы в пользу изменения.

Выполнение регулярного выражения по неопределенному значению вызовет ошибку из-за ошибки и приведет к выходу кода во многих, если не в большинстве средах. Тестирование, если значение определено или задание по умолчанию, как я сделал в альтернативном примере перед запуском выражения, как минимум, сохранит ваш журнал ошибок.

Автор: Jason Van Patten Размещён: 21.09.2013 04:14

-1 плюса

Эта функция работает для меня:

    sub IS_Integer() 
    {
        my $Text = shift;
        my $Integer = 0;

        if ($Text =~ /\D/)
        {
            $Integer = 1;
        }
        if ($Text =~ /^\d+$/)
        { 
            $Integer = 1;
        }
        if ($Text =~ /^-?\d+$/)       
        { 
            $Integer = 1;
        }
        if ($Text =~ /^[+-]?\d+$/)    
        { 
            $Integer = 1; 
        }
        if ($Text =~ /^-?\d+\.?\d*$/) 
        {
            $Integer = 1; 
        }
        if ($Text =~ /^-?(?:\d+(?:\.\d*)?&\.\d+)$/) 
        {
            $Integer = 1;
        }
        if ($Text =~ /^([+-]?)(?=\d&\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
        {
            $Integer = 1;
        }

        return $Integer;
    }
Автор: Mohamad Hamouday Размещён: 18.05.2017 09:08
Вопросы из категории :
32x32